如何成为时间领主 - 诞生

好人不需要规则。

神秘博士

要成为日期和时间的主人并不是一件容易的事，在任何编程语言中，这总是一个问题，有时会让人感到困惑，我们将澄清并提出一些提示，使这项任务尽可能简单。

坐上TARDIS，我将把你变成一个时间领主。

让我们从基本知识开始

如果你通常使用其他语言，请记住，Intersystems Object Script（以下简称IOS，不要与苹果手机混淆）的日期有点特殊。
当我们在终端运行$HOROLOG  命令时，为了得到当前的日期和时间，你会看到它被分为两部分：

WRITE $HOROLOG

> 66149,67164

第一个值是天数，确切地说，是自1840年12月31日以来的天数，也就是说，值1是1841年1月1日；第二个值是自今天00:00以来的秒钟。

在这个例子中，66149对应于09/02/2022（欧洲格式的日/月/年的2月9日），67164对应于18:39:24。我们将这种格式称为数据和时间的内部格式。

感到困惑吗？好吧，我们将开始揭示宇宙的伟大秘密（日期和时间）。

 

如何将内部格式转换为更清晰的格式？

为此，我们将用到命令 $ZDATETIME

基本的命令是

SET RightNow = $HOROLOG
WRITE RightNow

> 66149,67164
WRITE $ZDATETIME(RightNow)

> 02/09/2022 18:39:24

默认情况下，它使用美国格式月/日/年（mm/dd/yyyy）。如果你想使用其他格式的日期，我们将使用第二个参数，比如欧洲格式日/月/年（dd/mm/yyyy），在这种情况下，我们将给它一个值4（关于更多的格式，见文档$ZDATETIME.dformat）。

SET RightNow = $HOROLOG
WRITE RightNow

> 66149,67164

WRITE $ZDATETIME(RightNow,4)

> 09/02/2022 18:39:24

该选项使用我们在本地变量中定义的分隔符和年份格式。

如果我们还想放另一种时间格式，例如12小时格式（AM/PM）而不是24小时格式，我们使用第三个参数，其值为3，如果我们不想显示秒，我们将使用值4（见文件$ZDATETIME.tformat）。

SET RightNow = $HOROLOG
WRITE RightNow

> 66149,67164

WRITE $ZDATETIME(RightNow,4,3)

> 09/02/2022 06:39:24PM

WRITE $ZDATETIME(RightNow,4,4)

> 09/02/2022 06:39PM

现在是不是更清楚了？那么让我们更深入地了解一下。

ODBC 格式

这个格式与你的本地配置无关，它将始终显示为年/月/日格式 yyyy-mm-dd，其值为3。 如果我们想创建要导出文件的数据，如CSV、HL7文件等，建议使用它。

SET RightNow = $HOROLOG
WRITE RightNow

> 66149,67164

WRITE $ZDATETIME(RightNow,3)

> 2022-02-09 18:39:24

一周的日子，星期名称，一年中的某天

如果我们只是想分别处理日期和时间，应该分别使用$ZDATE和$ZTIME命令。格式的参数与 $ZDATETIME.dformat 和 $ZDATETIME.tformat中定义的参数相同。

SET RightNow = $HOROLOG
WRITE RightNow

> 66149,67164

WRITE $ZDATE(RightNow,10)

> 3

WRITE $ZDATE(RightNow,11)

> Wed

WRITE $ZDATE(RightNow,12)

> Wednesday

那我如何将日期转换为内部格式？

好了，现在我们来看看相反的步骤，即有一个带有日期的文本，并将其转换成IOS格式。对于这个任务，我们将使用命令 $ZDATETIMEH。

这一次，我们必须指出日期和时间的格式（如果我们使用$ZDATETIMEH），或者分别指出日期（$ZDATEH）和时间（$ZTIMEH）。

格式是相同的，也就是说，如果我们有一个ODBC格式（yyyy-mm-dd）的日期字符串，那么我们将使用值3。

SET MyDatetime = "2022-02-09 18:39:24"
SET Interna1 = $ZDATETIMEH(MyDatetime, 3, 1) // ODBC Format

SET MyDatetime = "09/02/2022 18:39:24"
SET Interna2 = $ZDATETIMEH(MyDatetime, 4, 1) // European format

SET MyDatetime = "02/09/2022 06:39:24PM"
SET Interna3 = $ZDATETIMEH(MyDatetime, 1, 3) // American format with time in 12h AM/PM
WRITE Interna1,!,Interna2,!,Interna3

> 66149,67164
66149,67164
66149,67164

从逻辑上讲，如果我们说字符串使用的是一种特殊的格式，而我们给它提供了错误的参数，那么任何事情都可能发生，比如它理解为2月9日，而不是9月2日。

不要混合格式，这样以后会出现问题。

SET MyDatetime = "09/02/2022"

/// American format
SET InternalDate = $ZDATEH(MyDatetime, 1) 

/// European format
SET OtherDate = $ZDATETIME(InternalDate, 4)
WRITE InternalDate,!,OtherDate

> 66354
02/09/2022

不用说，如果我们试图设定一个欧洲的日期并试图将其转化为美国的日期...... 在情人节会发生什么？

SET MyDatetime = "14/02/2022"
SET InternalDate = $ZDATEH(MyDatetime, 1) // American format. month 14 doesn't exists!!!
^
<ILLEGAL VALUE>

嗯，就像所有的情人节一样......破碎的心，嗯......在这种情况下，破碎的代码。

好吧，让我们用你已经学到的东西做一些事情。

READ !,"Please indicate your date of birth (dd/mm/yyyy): ",dateOfBirth
SET internalFormat = $ZDATEH(dateOfBirth, 4)
SET dayOfWeek= $ZDATE(internalFormat, 10)
SET nameOfDay = $ZDATE(internalFormat, 12)
WRITE !,"The day of the week of your birth is: ",nameOfDay
IF dayOfWeek = 5 WRITE "you always liked to party!!!" // was born on friday

以后我们将看到其他的做事方法，以及如何处理错误。

 

下一章：如何进行时间旅行

 

好奇

如果你想知道为什么01/01/1841的值被当作1的值，那是因为选择这个日期是因为它是在世的最年长的美国公民出生前的非闰年，当MUMPS编程语言被设计时，他是一个121岁的内战老兵，它从这个语言中扩展了对象脚本。